MySQLDatabases/pl

From Lazarus wiki
Jump to navigationJump to search

│ Deutsch (de) │ English (en) │ français (fr) │ 日本語 (ja) │ polski (pl) │ slovenčina (sk) │

Portal bazy danych

Bibliografia:

Poradniki/porady praktyczne:

Bazy danych

Advantage - MySQL - MS SQL - Postgres - Interbase - Firebird - Oracle - ODBC - Paradox - SQLite - dBASE - MS Access - Zeos

Wprowadzenie

Ta strona wyjaśnia, jak połączyć się z serwerem bazy danych MySQL przy użyciu komponentów wizualnych.

Light bulb  Uwaga: Ta strona została przetłumaczona z wersji angielskiej na język polski w dniu 2021.01.31, ale wersja angielska została napisana dawno temu i może nie być aktualna. Ponadto większość opisanych tutaj koncepcji nie jest specyficznych dla MySQL, ale ma zastosowanie do wszystkich baz danych SQLDB. Dlatego skorzystanie z poniższej serii samouczków SQLdb może być łatwiejsze

Uwaga: zapoznaj się również z samouczkami, które uczą obsługi kontrolek związanych z danymi, zapytań parametrycznych, programowania niezależnego od bazy danych itp .:

Te samouczki są napisane dla wszystkich baz danych obsługujących sqldb, w tym MySQL.

W razie potrzeby zobacz również Samouczki SQLDB i przykładowy kod, aby uzyskać więcej samouczków (które również zostały napisane dawno temu.

Dostępne komponenty

Komponenty SQLdb

W każdej, nawet dość niedawnej wersji Lazarusa, komponenty SQLdb są instalowane domyślnie.

sqldbcomponents2.png

W zakładce SQLdb znajdziesz:

  • Różne złącza (connectors), w tym TMySQL40Connection .. TMySQL57Connection (a może nawet nowsze wersje) i najbardziej wszechstronne ze wszystkich TSQLConnector, które mogą ładować dowolne ze sterowników baz danych takich jak mysql/oracle/postgres/mssql/interbase/firebird/odbc.
  • TSQLQuery

Jeśli brakuje karty SQLdb, zajrzyj do Instalowanie pakietów, aby uzyskać instrukcje dotyczące instalacji.

Wyjaśnienie zastosowanych komponentów

TMySQLConnection

TMySQLConnection służy do przechowywania parametrów połączenia z serwerem bazy danych. Umożliwia ustawienie hosta, z którym ma się łączyć, oraz identyfikatora użytkownika i hasła, które mają być używane w połączeniu. Inna właściwość TMySQLConnection służy do wskazania bazy danych, której chcesz użyć. „LoginPrompt” jeszcze nie działa, więc upewnij się, że obok właściwości HostName i DatabaseName uzupełnione są również wartości UserName i Password, zanim spróbujesz otworzyć połączenie. Pamiętaj, że aby użyć również TSQLTransaction i połączyć ją z MySQLConnection, ustaw właściwość Transaction, w przeciwnym razie nie będziesz mógł otworzyć zapytania SQLQuery.

Light bulb  Uwaga: Jak wskazano powyżej, istnieją różne komponenty MySQLConnection, które różnią się numerem wersji. Numer wersji musi odpowiadać numerowi wersji biblioteki klienta, której używasz do łączenia się z serwerem. Jeśli więc używasz serwera MySQL 5.1, ale używasz klienta MySQL 5.0, użyj TMySQL50Connection.

Powinieneś sprawdzić dokumentację MySQL, aby upewnić się, że połączenie między wersją klienta i wersją serwera jest obsługiwane - np. możesz mieć problemy z połączeniem się z serwerem 4.0 przy użyciu klienta 5.x.

We wszystkich przypadkach należy umieścić kopię biblioteki libmysql.dll i wszelkich innych wymaganych plików/bibliotek dll

  • w twoim katalogu Lazarus i tym samym katalogu co pliki twojego projektu lub
  • w katalogu systemowym Windows (jeśli nie chcesz dalej kopiować plików). Zauważ, że w 64-bitowym systemie Windows bibliotekę 32-bitową musisz umieścić w katalogu SysWOW64, podczas gdy biblioteki 64-bitowe należy przenieść do System32.

TSQLTransaction

TSQLTransaction jest potrzebne do niektórych wewnętrznych procedur. SQLTransaction jest automatycznie aktywowana po otwarciu zestawu danych przy jej użyciu. Zamknięcie połączenia również dezaktywuje powiązaną transakcję i zamyka wszystkie korzystające z niej zbiory danych.

TSQLQuery

TSQLQuery służy do wykonywania instrukcji SQL na serwerze. Możesz pobrać dane, ustawiając SQL na jakąś instrukcję SELECT i wywołując metodę Open. Możesz też manipulować danymi, wydając instrukcję INSERT, DELETE lub UPDATE. W tym drugim przypadku nie powinieneś używać metody Open, ale metodę ExecSQL.

TDataSource

TDataSource zapewnia połączenie między widocznymi komponentami obsługującymi dane, takimi jak DBEdit, DBGrid i zbiorem danych. Przygotowuje dane do wyświetlania w komponentach obsługujących te dane. DataSource (źródło danych) może być jednocześnie połączone tylko z jednym zestawem danych, ale do niego może być połączonych kilka komponentów obsługujących dane.

TDBGrid

TDBGrid może służyć do przedstawienia danych pobranych przez Dataset (zbiór danych). DBGrid potrzebuje Datasource (źródła danych), aby połączyć się ze zbirem danych. Gdy zbiór danych zostanie otwarty, DBGrid zostanie automatycznie wypełniony danymi.

Nasz program

Podstawy

Spróbujemy stworzyć program w oparciu o ten stworzony tutaj (w języku niderlandzkim), który jest oparty na oryginale (w języku angielskim) autorstwa Chris.

Formularz główny

Użyjemy tego samego ekranu głównego i zbudujemy całą funkcjonalność od podstaw :) Jak zobaczysz, jest tu o wiele mniej do zrobienia, ponieważ komponenty naprawdę rozwiązują wszystkie trudne rzeczy! Zacznijmy więc od stworzenia ekranu, który wygląda tak:

Trymysql pl.png

Korzystając z zakładki SQLdb umieść na swojej formatce komponenty TMySQL56Connection tmysql56connection.png (lub inną wersję klienta mysql), TSQLTransaction tsqltransaction.png i TSQLQuery tsqlquery.png. Nie zmieniaj domyślnych nazw nadanych tym komponentom. Z wyjątkiem komponentu łączącego do bazy. Aby artykuł był taki sam dla wszystkich wersji MySQL, nazwij komponent TMySQL##Connection: MySQLConnection1. Musimy te komponenty połączyć razem, aby mogły wykonywać swoją pracę. Dlatego należy ustawić następujące właściwości:

Komponent Właściwość Wartość
MySQLConnection1 Transaction SQLTransaction1
SQLTransaction1 Database MySQLConnection1
SQLQuery1 Transaction SQLTransaction1
SQLQuery1 Database MySQLConnection1

Właściwość Transaction komponentu SQLQuery1 zostanie ustawiona automatycznie, jeśli najpierw ustawisz właściwość Transaction dla MySQLConnection1. Gdy to ustawisz, zauważysz, że SQLTransaction1.Database została ustawiona na MySQLConnection1.

Jak wspomniano wcześniej: upewnij się, że używasz odpowiedniego komponentu połączenia dla swojej wersji serwera MySQL.

Kod

Jak widać na zrzucie ekranu, jedynymi przyciskami dostępnymi po uruchomieniu programu są „Połącz z serwerem” i „Zakończ”. Aby inne przyciski działały, potrzebujemy więcej informacji, więc są one wyłączone. Moglibyśmy również zdecydować o wyłączeniu opcji „Połącz z serwerem” do czasu podania informacji o hoście, nazwie użytkownika i haśle. Zdecydowałem się tego nie robić, ponieważ nasz użytkownik mógłby pomyśleć: „Nic nie wydaje się możliwe, więc przejdźmy do wyjścia”. :)

Zanim zacznę podawać jakikolwiek kod, chciałbym podkreślić, że w kodzie powinna być dodana obsługa wyjątków. Sekcje krytyczne należy umieścić w blokach kodu 

try ... finally

i / lub 

try ... except

Połączenie z serwerem

Pierwszą rzeczą, którą musimy zrobić, jest połączenie się z naszym serwerem. Ponieważ przy łączeniu nie wiemy, jakie bazy danych są dostępne na serwerze, przy połączeniu poprosimy o listę baz danych. Jest jednak jeden haczyk, aby nawiązać połączenie, musimy wprowadzić poprawną nazwę bazy danych we właściwościach MySQLConnection. W kodzie zobaczysz, że używam bazy danych „mysql”. Ta baza danych jest używana przez mysql do pewnych czynności porządkowych, więc zawsze tam będzie. 

procedure TFormTryMySQL.ConnectButtonClick(Sender: TObject);
begin
  // Sprawdź, czy mamy aktywne połączenie. Jeśli tak, musimy je zamknąć.
  if MySQLConnection1.Connected then CloseConnection(Sender);
  // Ustaw parametry połączenia.
  MySQLConnection1.HostName := HostEdit.Text;
  MySQLConnection1.UserName := UserEdit.Text;
  MySQLConnection1.Password := PasswdEdit.Text;
  MySQLConnection1.DatabaseName := 'mysql'; // Baza mysql jest zawsze dostępna!
  ShowString('Otwarcie połączenia z serwerem: ' + HostEdit.Text);
  MySQLConnection1.Open;
  // Najpierw pobierzmy listę dostępnych baz danych.
  if MySQLConnection1.Connected then begin
    ShowString('Połączono z serwerem: ' + HostEdit.Text);
    ShowString('Pobieranie listy dostępnych baz danych.');
    SQLQuery1.SQL.Text := 'show databases';
    SQLQuery1.Open;
    while not SQLQuery1.EOF do begin
      DatabaseComboBox.Items.Add(SQLQuery1.Fields[0].AsString);
      SQLQuery1.Next;
    end;
    SQLQuery1.Close;
    ShowString('Lista otrzymanych baz danych!');
  end;
end;

Pierwszą rzeczą, jaką robimy, jest sprawdzenie, czy jesteśmy połączeni z serwerem, jeśli tak, wywołujemy prywatną metodę „CloseConnection”. W tej metodzie robi się więcej porządków. jak wyłączanie przycisków i czyszczenie comboboxów i listbox. Następnie ustawiamy niezbędne parametry, aby połączyć się z serwerem.

W całym naszym programie możesz zobaczyć wywołania ShowString. Ta metoda dodaje wiersz do notatki w naszym formularzu, który działa jak rodzaj dziennika.

Po ustawieniu parametrów możemy połączyć się z serwerem. Odbywa się to przez wywołanie 

MySQLConnection1.Open;

W odpowiedniej aplikacji można by to umieścić w konstrukcji obsługi wyjątków, aby przedstawić użytkownikowi przyjazny komunikat w przypadku niepowodzenia połączenia. Kiedy jesteśmy połączeni, chcemy uzyskać listę baz danych z serwera. Aby uzyskać dane z serwera, używane jest zapytanie TSQLQuery. Właściwość SQL służy do przechowywania instrukcji SQL wysyłanej do serwera. MySQL zna polecenie „SHOW DATABASES”, aby uzyskać listę baz danych. Więc po ustawieniu tekstu SQL wywołujemy 

SQLQuery1.Open;

W MySQL5 ustaw to, aby poprawić błąd ze składnią SQL: 

SQLQuery1.ParseSQL := False; 
SQLQuery1.ReadOnly := True;

Zestaw wyników SQLQuery można sprawdzić za pomocą właściwości fields. Jak widać, przeglądamy wszystkie zapisy, wywołując 

SQLQuery1.Next;

Kiedy dodamy wszystkie dostępne bazy danych do naszego combobox, ponownie zamykamy SQLQuery.

Wybieranie bazy danych

Jeśli użytkownik wybierze bazę danych w DatabaseComboBox, włączamy przycisk „Wybierz bazę danych”. W zdarzeniu OnClick tego przycisku ustawiamy DatabaseName MySQLConnection1 i żądamy listy tabel. Ostatnia instrukcja tej procedury włącza przycisk „Otwórz zapytanie”, dzięki czemu użytkownik może wprowadzić zapytanie w polu edycji „Polecenie” i wysłać je na serwer. 

procedure TFormTryMySQL.SelectDBButtonClick(Sender: TObject);
begin
  // Baza danych została wybrana, więc pobierzmy z niej tabele.
  CloseConnection(Sender);
  if DatabaseComboBox.ItemIndex <> -1 then begin
    with DatabaseComboBox do
      MySQLConnection1.DatabaseName := Items[ItemIndex];
    ShowString('Pobieranie listy tabel');
    SQLQuery1.SQL.Text := 'SHOW TABLES';
    SQLQuery1.Open;
    while not SQLQuery1.EOF do begin
      TableComboBox.Items.Add(SQLQuery1.Fields[0].AsString);
      SQLQuery1.Next;
    end;
    SQLQuery1.Close;
    ShowString('Lista otrzymanych tabel');
  end;
  OpenQueryButton.Enabled := True;
end;

MySQL ma specjalne polecenie do pobierania listy tabel, porównywalne do pobierania listy baz danych, „SHOW TABLES”. Wynik tego zapytania jest obsługiwany w taki sam sposób, jak lista baz danych, a wszystkie tabele są dodawane do TableComboBox. Możesz się zastanawiać, dlaczego nie otwieramy ponownie połączenia przed otwarciem zapytania? Cóż, odbywa się to automatycznie (jeśli to konieczne), gdy aktywujemy SQLQuery.

Pola w tabeli

W MySQL możesz ponownie użyć formy „SHOW”, aby pobrać pola w tabeli. W tym przypadku „SHOW COLUMNS FROM <nazwa tabeli>”. Jeśli użytkownik wybierze tabelę z TableComboBox, wyzwalane jest zdarzenie OnChangeEvent tego ComboBox, które wypełnia pole FieldListbox. 

procedure TFormTryMySQL.TableComboBoxChange(Sender: TObject);
begin
  FieldListBox.Clear;
  SQLQuery1.SQL.Text := 'SHOW COLUMNS FROM ' + TableComboBox.Text;
  SQLQuery1.Open;
  while not SQLQuery1.EOF do begin
    FieldListBox.Items.Add(SQLQuery1.Fields[0].AsString);
    SQLQuery1.Next;
  end;
  SQLQuery1.Close;
end;

Oprócz nazw pól, zestaw wyników zawiera informacje o typie pola, jeśli pole jest kluczem, czy dozwolone są wartości null i nie tylko.

Wyświetlanie danych

Tak jak powiedzieliśmy, użyjemy komponentów do połączenia się z bazą danych, użyjmy również niektórych komponentów, aby pokazać dane. W drugim formularzu pokażemy siatkę z danymi żądanymi przez użytkownika. Formularz ten zostanie wyświetlony, gdy użytkownik wpisze polecenie SQL w polu edycji „Polecenie”, a następnie kliknie przycisk „Otwórz zapytanie”. To jest zdarzenie OnClick: 

procedure TFormTryMySQL.OpenQueryButtonClick(Sender: TObject);
begin
  ShowQueryForm := TShowQueryForm.Create(self);
  ShowQueryForm.Datasource1.DataSet := SQLQuery1;
  SQLQuery1.SQL.Text := CommandEdit.Text;
  SQLQuery1.Open;
  ShowQueryForm.ShowModal;
  ShowQueryForm.Free;
  SQLQuery1.Close;
end;

ShowQueryForm wygląda następująco:

Mysqlshow pl.png

i zawiera

TPanel Align alBottom
TDataSource
TDBGrid Align alClient
DataSource DataSource1
TButton Caption Close

Przycisk umieszczony jest na panelu. Kolejność działań w OnClick przycisku „Otwórz zapytanie” jest następująca. Najpierw tworzymy wystąpienie TShowQueryForm. Po drugie ustawiliśmy właściwość DataSet źródła danych na nasz SQLQuery1. Następnie ustawiamy polecenie SQLQuery SQL na to, co użytkownik wpisał w polu edycji „Polecenie” i otwieramy je. Następnie ShowQueryForm jest pokazywany modalnie, co oznacza, że ​​będzie się na nim koncentrował, dopóki nie zostanie zamknięty. Po zamknięciu „zwalniamy” go i ponownie zamykamy SQLQuery1.

Formularz można dodatkowo ulepszyć poprzez wstawienie metody modyfikowania zawartości TDataSet i ostatecznie DataBase. Pełną wersję można pobrać z http://digitus.itk.ppke.hu/~janma/lazarus/MySql5Test.tar.gz (dzięki Arwen i JZombi z Lazarus MySQL Forum) ale istotne szczegóły są następujące:

Dodaj przycisk u dołu formularza ShowQuery o nazwie AddButton i podpisem „Dodaj”. Utwórz metodę dla AddButtonClick w następujący sposób: 

procedure TShowQueryForm.AddButtonClick(Sender: TObject);
begin
  DataSource1.DataSet.Append;
end;

Zmień kod dla OpenQueryButtonClick, aby umożliwić aktualizacje bazy danych po zakończeniu pracy z formularzem zapytania. 

procedure TFormTryMySQL.OpenQueryButtonClick(Sender: TObject);
begin
  ShowQueryForm := TShowQueryForm.Create(nil);
  try
    ShowQueryForm.DataSource1.DataSet := SQLQuery1;
    // Będziemy pisać w bazie danych, więc ustawmy ReadOnly na false,
    // a do tego musimy ustawić ParseSQL na true
    SQLQuery1.ParseSQL:=true;
    SQLQuery1.ReadOnly:=false;
    SQLQuery1.SQL.Text := CommandEdit.Text;
    SQLQuery1.Open;
    ShowQueryForm.ShowModal;
  finally
    // ustaw tryb aktualizacji i zaktualizuj bazę danych
    SQLQuery1.UpdateMode:=upWhereChanged;
    SQLQuery1.ApplyUpdates;
    SQLTransaction1.Commit;
    ShowQueryForm.Free;
    SQLQuery1.Close;
    // ustaw ReadOnly i ParsesSQL z powrotem na domyślne
    SQLQuery1.ParseSQL:=false;
    SQLQuery1.ReadOnly:=true;
  end;
end;

Możemy teraz dodawać rekordy do bazy danych. Jeśli dodamy TDBNavigator do formularza ShowQuery, możemy łatwiej poruszać się po siatce danych i edytować rekordy; baza danych jest aktualizowana o nasze zmiany za każdym razem, gdy zamykamy formularz ShowQuery i możemy to przetestować, otwierając go ponownie w celu sprawdzenia bazy danych.

Jeśli chcesz mieć możliwość USUWANIA lub w inny sposób modyfikowania rekordów w oryginalnej bazie danych (tj. trzeba upewnić się, że zmiany wprowadzone w lokalnym zestawie danych zostaną zatwierdzone z powrotem w bazie danych), musisz mieć jedną kolumnę w tabeli bazy danych, która jest kluczem podstawowym autoincremented, ponieważ metoda 'delete' wymaga możliwości wygenerowania klauzuli 'where' podczas zapisywania instrukcji z powrotem do bazy danych, aby zidentyfikować rekordy wybrane do usunięcia. Użyj więc następującego kodu w swoim kliencie MySQL (wszystko może być wpisane w jednej linii, ale dla przejrzystości dodano podziały linii): 

ALTER TABLE TRESTRIG 
ADD COLUMN AUTOID INT 
PRIMARY KEY AUTO_INCREMENT;

a wtedy zauważysz, że przycisk Usuń w nawigatorze działa.

Źródła

Oryginalne źródła tego projektu można pobrać tutaj. Aby uzyskać więcej projektów demonstracyjnych, zobacz sourceforge.

Light bulb  Uwaga: Projekty te powstały w latach 2004-2009 i nie były aktualizowane. Bez kilku poprawek mogą nie kompilować się w obecnym Lazarus 2.0.10.

Zobacz także

Retrieved from "https://wiki.freepascal.org/index.php?title=MySQLDatabases/pl&oldid=147848"